
	.include "KF8S1011.inc"
	
	;;// 汇编编写说明 实体建立后应该选择文件前面添加（可共C和汇编引用)

	;// .global	 (实体)  

	;;// 汇编编写说明 引用调用前应该选择文件前面添加 （引用)

	;// .extern  （引用)

;--------------------------------------------------------
; external declarations
;--------------------------------------------------------
	.extern	_init_mcu
	.extern _TOUCH_DEBUG_SEND_OUT
	.extern	_TOUCH_DEBUG_TRS_DEAL


	.extern	__KF8_LIBi_channel_flag_ 
	.extern	__KF8_LIBc_channel_
	
	.extern START_INIT
	.extern __R2PCL
	.extern _cinit	

;//获取版本
	.extern	__KF8S_Get_Ver_General_
;// 参数更换   0：选用 T1H T1L PWM不可用 ； 1：选用T1U，T3L但仅适合E03版本芯片；2：选用T1U，T3L，满足E05及以后版本芯片。
	.extern	__KF8S_Lib_Set_General_Parameter
;//初始化电容触摸
	.extern	__KF8S_Init_Touch_General_
;//电容触摸通道处理
	.extern	__KF8S_Touch_Process_General_
;//简化接收开启函数，仅调试曲线时用
	.extern	_KF8S_Touch_TEST_General_
;--------------------------------------------------------
; global declarations
;--------------------------------------------------------
	.global	_delay_us
	.global	_delay_ms
	.global	_display
;--------------------------------------------------------
	.global _STK03
	.global _STK02
	.global _STK01
	.global _STK00	

_MAIN_RAM_0	.udata  
_STK03	.res	1
_STK02	.res	1
_STK01	.res	1
_STK00	.res	1
;--------------------------------------------------------
; 开机入口准备工作
;--------------------------------------------------------
STARTUP	.code 0x0000
	NOP
	PAGESEL	init_imp		;// 初始化代码综合入口
	JMP		init_imp
	
INIT_IMP	.code
init_imp

	PAGESEL		START_INIT	
	CALL		START_INIT	;// 校准值调入
	PAGESEL	$	
	
	PAGESEL		_cinit	
	CALL		_cinit		;// 编译所需 做变量初始值处理 idate
	PAGESEL	$	
		
	PAGESEL	_main	
	JMP		_main	
;--------------------------------------------------------
; 中断函数入口 注意压栈  需要注意  PSW BANK PCH R0 R1 更过Rx根据代码和中断代码的使用情况处理
; 1级中断芯片示例如下  不带BANK寄存器  使用 R2 R3 R4 R5保存现场
; 2级中断需要建立额外变量配置Rx寄存器进行中断的现场保护，如V216demo汇编样例
;--------------------------------------------------------
c_interrupt	.code	0x4
;压栈保护
	MOV		R3,R0
	MOV		R4,PSW
	MOV		R5,PCH
	MOV		R2,R1
	PAGESEL	__sdcc_interrupt
	JMP		__sdcc_interrupt

func.__sdcc_interrupt .code
__sdcc_interrupt
;	if(T1IF)
	JB	EIF1, 0
	JMP	__sdcc_interrupt_out
;	T1IF=0;
	CLR	EIF1, 0
;
	CWDT 

;	_KF8S_Touch_Process_General_(); //更新按键标志 ，可以做标志，主循环查询处理
	PAGESEL	__TOUCH_DEBUG_TRS_DEAL
	CALL	__TOUCH_DEBUG_TRS_DEAL
	PAGESEL	$
	
	PAGESEL	__KF8S_Touch_Process_General_
	CALL	__KF8S_Touch_Process_General_
	PAGESEL	$
;出栈还原	
__sdcc_interrupt_out
	MOV	R1, R2
	MOV	PCH, R5
	MOV	PSW, R4
	MOV	R0, R3
	IRET	
;--------------------------------------------------------
; 主程序main入口
;--------------------------------------------------------
func._main	.code
_main
;	init_mcu();			//初始化MCU寄存器
	PAGESEL	_init_mcu
	CALL	_init_mcu
	PAGESEL	$
;//------------------------------------------
;	CMCTL1 = 0x20;    		//设置触摸分频和基准电压
	MOV	R0,# 0x90
	MOV	CMCTL1, R0
;//------------------------------------------
	CWDT 
;	delay_ms(500);					//使能等待电源稳定，采样作为基准
	MOV	R0,# 0x00					;;高位
	BANKSEL	_STK00
	MOV	_STK00, R0
	MOV	R0,# 0xC8					;;低位
	PAGESEL	_delay_ms
	CALL	_delay_ms
	PAGESEL	$
;//------------------------------------------
;__KF8S_Lib_Set_General_Parameter(1)
	MOV R0,#0x01
	PAGESEL __KF8S_Lib_Set_General_Parameter
	CALL __KF8S_Lib_Set_General_Parameter
	PAGESEL $
;	_KF8S_Init_Touch_General_;		//调用电容触摸库函数的初始化
	PAGESEL	__KF8S_Init_Touch_General_
	CALL	__KF8S_Init_Touch_General_
	PAGESEL	$	
;//------------------------------------------
_Main_LooP_Code
	CWDT 
;	display();					//显示LED灯
	PAGESEL	_display
	CALL	_display
	PAGESEL	$
	
;	delay_ms(1);
	MOV	R0,# 0x00					;;高位
	BANKSEL	_STK00
	MOV	_STK00, R0
	MOV	R0,# 0x01					;;低位
	PAGESEL	_delay_ms
	CALL	_delay_ms
	PAGESEL	$
	
	
	JMP	_Main_LooP_Code
;//------------------------------------------
	CRET	
;--------------------------------------------------------
; 微秒级别延时函数//  USE  R1 R0 传递循环次数
;--------------------------------------------------------
func._delay_us	.code
_delay_us	 ;不需要切区
; void delay_us(uint us_data)
;;	while(us_data--);
_delay_us_loop1
 	DEC  R0
 	JB   PSW,Z   
 	JMP _delay_us_loop1
 	
 	XOR R1,#0x00
 	JNB PSW,2
 	JMP _delay_us_loop_end
 	DEC   R1
 	MOV  R0,#0xFF
 	JMP _delay_us_loop1 	
_delay_us_loop_end 
	CRET	
;--------------------------------------------------------
; 毫秒级别延时函数  use STK00 R0
;--------------------------------------------------------
func._delay_ms	.code
_delay_ms	;
;; void delay_ms(uint ms_data)  use STK00,R0,最小值1
;	while(ms_data--)
;	j=200;  CWDT
;	while(j--)	

_delay_ms_Deal	  ;j=200;  CWDT
    MOV R1,#0xC8
    CWDT
 	;while(j--)
_delay_ms_sub
    DEC  R1
	JB   PSW,Z
 	JMP  _delay_ms_sub
	; ms_data
 	DEC R0
 	JB  PSW,Z 	
 	JMP _delay_ms_Deal   ;低8位不借位时继续 	
 	
 	MOV R1,#0x00
 	BANKSEL _STK00
 	XOR _STK00,R1
 	JNB PSW,2
 	JMP _delay_ms_loop_end 
 	BANKSEL _STK00
 	DEC _STK00
 	MOV  R0,#0xFF
 	JMP _delay_ms_Deal  ;高位为零计数，否则借位到低
 	
_delay_ms_loop_end 	
	CRET
;--------------------------------------------------------
; 按键结果输出指示函数,根据标志长度，根据需求进行解析代码编写
;--------------------------------------------------------
func._display	.code
_display	;Function start
;//----------------------------------------------------	
;if(_KF8_LIBi_channel_flag_&0x0001)		//通道0
	BANKSEL	__KF8_LIBi_channel_flag_
	JB	__KF8_LIBi_channel_flag_, 0
	JMP	__display_DS_0002
;	LED1=1;
	BANKSEL P3	
	SET	P3, 7
	JMP	__display_DS_0003
__display_DS_0002
;	LED1=0;
	BANKSEL P3	
	CLR	P3, 7
;//----------------------------------------------------		
__display_DS_0003
;	if(_KF8_LIBi_channel_flag_&0x0002)		//通道2
	BANKSEL	__KF8_LIBi_channel_flag_
	JB	__KF8_LIBi_channel_flag_, 1
	JMP	__display_DS_0005
;	LED2=1;
	BANKSEL P3	
	SET	P3, 6
	JMP	__display_DS_0006
__display_DS_0005
;	LED2=0;
	BANKSEL P3
	CLR	P3, 6
;//----------------------------------------------------		
__display_DS_0006
;	if(_KF8_LIBi_channel_flag_&0x0004)		//通道4
	BANKSEL	__KF8_LIBi_channel_flag_
	JB	__KF8_LIBi_channel_flag_, 2
	JMP	__display_DS_0007
;	LED3=1;
	BANKSEL P3	
	SET	P3, 5
	JMP	__display_DS_0008
__display_DS_0007
;	LED3=0;
	BANKSEL P3	
	CLR	P3, 5
;//----------------------------------------------------		
__display_DS_0008
;	if(_KF8_LIBi_channel_flag_&0x0008)		//通道3
	BANKSEL	__KF8_LIBi_channel_flag_
	JB	__KF8_LIBi_channel_flag_, 3
	JMP	__display_DS_0009
;	LED4=1;
	BANKSEL P3	
	SET	P3, 4
	JMP	__display_DS_0010
__display_DS_0009
;	LED4=0;
	BANKSEL P3	
	CLR	P3, 4
;//----------------------------------------------------			
__display_DS_0010
;	if(_KF8_LIBi_channel_flag_&0x0010)		//通道4
	BANKSEL	__KF8_LIBi_channel_flag_
	JB	__KF8_LIBi_channel_flag_, 4
	JMP	__display_DS_0011
;	LED5=1;
	BANKSEL P3	
	SET	P3, 3
	JMP	__display_DS_0012
__display_DS_0011
;	LED5=0;
	BANKSEL P3	
	CLR	P3, 3
;//----------------------------------------------------			
__display_DS_0012
;	if(_KF8_LIBi_channel_flag_&0x0020)		//通道5
	BANKSEL	__KF8_LIBi_channel_flag_
	JB	__KF8_LIBi_channel_flag_, 5
	JMP	__display_DS_0013
;	LED6=1;
	BANKSEL P3	
	SET	P3, 0
	JMP	__display_DS_0014
__display_DS_0013
;	LED6=0;
	BANKSEL P3	
	CLR	P3, 0
;//----------------------------------------------------		
__display_DS_0014
	;..............................
	CRET	
; exit point of _display


	.end
